' 
' prtrap -  Prints all trap information onto the console
'


' --------------------------------------------------
' Check usage & arguments
' --------------------------------------------------
Set Sout = WScript.StdOut

if WScript.Arguments.Count <> 1 then
	Sout.WriteLine "Usage: prtrap <trap-database>"
	WScript.Quit
end if
TrpFile    = WScript.Arguments.Item(0)

' --------------------------------------------------
' Create and load the database into the trap manager
' --------------------------------------------------
Set TrapMgr = CreateObject("UnbrowseSNMP.TrapReceiver")
TrapMgr.Load(TrpFile)
Sout.WriteLine "Loaded Trap Database File OK : " & TrpFile
Sout.WriteLine "Total Traps in database =  " & TrapMgr.TrapCount

' --------------------------------------------------
' Create the repository manager, used to translate OID to name
' --------------------------------------------------
Set RepMgr = CreateObject("UnbrowseSNMP.RepositoryManager")
Set RepDB  = RepMgr.LoadRepository
Sout.WriteLine "Created rep manager" 

' --------------------------------------------------
' Loop and process each trap
' --------------------------------------------------
NumTraps = TrapMgr.TrapCount
For TI = 0 To  NumTraps - 1
	Set OneTrap = TrapMgr.GetTrapByIdx(TI)
	PrintTrap OneTrap
Next

Sout.WriteLine "Finished" 


' ---------------------------------------------------
' PrintTrap : Subroutine
'	Dumps almost all trap information onto screen
' ---------------------------------------------------
Sub PrintTrap (OneTrap)
	' --------------------------
	' Print all trap information 
	' --------------------------
	Sout.WriteLine " ------------------------------------------" 
	Sout.WriteLine " Trap ID    : " & OneTrap.ID
	Sout.WriteLine " OID        : " & OneTrap.EffectiveTrapOID
	Sout.WriteLine " Name       : " & RepDB.OIDToName(OneTrap.EffectiveTrapOID)
	Sout.WriteLine " From Agent : " & OneTrap.AgentAddress
	Sout.WriteLine " To Manager : " & OneTrap.DestinationAddress
	Sout.WriteLine " Timestamp  : " & OneTrap.TimestampLocal
	Sout.WriteLine " OID        : " & OneTrap.EffectiveTrapOID
	Sout.WriteLine " User/Comm  : " & OneTrap.UserCommunity
	Sout.WriteLine " Varbinds   : " & OneTrap.VarbindCount

	' --------------------------
	' Print all varbinds in trap
	' --------------------------
	Sout.WriteLine " --------- Varbind list ----------" 
	For I = 0 To OneTrap.VarbindCount - 1
		Set OneVar = OneTrap.GetVarbindByIdx(I)
		Sout.Write vbTab & " " & I+1 & " ) " 
		Sout.WriteLine  OneVar.OID & "[" & RepDB.OIDToName(OneVar.OID) & "] = " &  OneVar.Value
	Next

	Sout.WriteLine vbCrLf

End Sub